Chapter 5

[i]Dex, sin!
*line_break
Dex, sin!
*line_break
Dex, sin![/i]

The Optio shouts the beat to our marching. Right, left, right, left… 

Rhythm is perfect; pain has made sure of that. Even Kegan marches with precision, he used to stumble on his feet for weeks. The beatings he received were a daily occurrence. Every time he stumbled, the Optio sent the other soldiers to clean the toilets. The resentment poor Kegan receives on a daily basis is appalling.

Floyd gives Kegan a glance, to make sure he stays in rhythm. From time to time, he erects his hand to touch Kegan's tunic, to make sure he remembers that he's not alone.

*fake_choice
    #Ignore them and focus on marching.
        *set disciplined +1
    #Look at him reassuringly. 
        *set group_friendship +1
        I, too, give Kegan a little reassuring look. You're doing great. You're keeping up with the seasoned soldiers, even if you're still a child.
    
        Kegan looks at me, almost forgetting to focus on his feet. He stumbles, almost; Floyd takes his arm to keep him standing.
    
        Someone hisses through his teeth: "If those fuckers ever get us into trouble again…"
    
        Kegan looks at me with his eyes wide open.
    
        'I'm sorry', I mouth at him.
*page_break

After an hour of marching my mind wanders, just to get my mind off from my aching feet. And back. And shoulders.

Everything, really. 

*if sex = "female"
    The bindings make breathing even more difficult. Every deeper breath I try to take sends jolts of pain to my chest. It takes a few more painful breaths to locate the source into my rib.

"[i]Claudio[/i]!" The Optio shouts and the marching stops. I just realize that we're back at the camp.

"Well, I'm glad that [i]some people[/i] managed to keep up with the rest of the actual soldiers." The Optio shoots a pointed look at us. I ignore the stare and my gaze wanders. Other soldiers pass us by, clearly on their way to the baths.

"And gods help me if I find you with a stained armor ever again," the Optio continues his rant that I barely listen to. The Optio looks at Pec, who gives the Optio a curt nod and tries to hide a stain of rust on his armor.

"Dismissed!" 

The men relax and start scattering about, their step heavy and sluggish. Just as I'm about to leave, Pec pokes me on my shoulder.

"You know, Hati…," he says, his forehead glistening. He looks sheepishly away. "I'm, erm… sorry about what happened during Samhain. I don't quite recall everything that took place but I take it that you didn't, umm, like it."

Maestus adds in: "You and Brick wrecked the place."

Pec purses his lips. "Yes, thank you."

Maestus continues: "We had to drag you away. You puked on your—"

"Yes! Thank you!"

*fake_choice
    #"It's fine." They couldn't know that what they were doing is dangerous.
        I suppose they're not blamed for their ignorance. The Romans are.
        
        Even if it still stings to think about the blasphemy that took place, I give Pec a little nod and repeat my words: "It's fine."
        
        He sighs in relief. "Thank the gods above, I was afraid that you took it way too seriously."
        
        I frown. I took it seriously because it was serious. 
        
        At the sight of my annoyance, he quickly retracts his words with a frantic shake of his head: "I mean, you should take it seriously. The ghosts and whatnot, and… Uh. Sorry!"
        
        His armor clanks loudly as he flees.
        
        Maestus and I look after him.
    #"I really didn't like it."
        My words are dry. It's still difficult to accept his apology. The images of what happened, the blasphemy that took place… It still stings my heart.
        
        Pec shifts his weight uncomfortably. "I, uh… I heard that you took it quite seriously."
        
        I squint my eyes at him. "It was serious."
        
        "I, uh, yes. Of course. Ghosts and whatnot, serious business. Yes. Well, sorry about that!"
        
        His armor clanks loudly as he flees.
        
        Maestus and I look after him.
    #Give him a glare and remain silent.
        I don't entertain his apology, nor do I plan on giving him any attention. "Was that it?" I ask.
        
        "Uh. Again. Sorry!" He yelps and starts moving away from me, his armor clanking as he flees.

*page_break
Maestus grunts silently: "For what it's worth, I'm sorry, too."

Before I can answer, I notice Floyd and Brick marching towards us. They glance at the escaping Pec before peering their gazes on me. 

What is this? They look ready for a fight. They are plotting something.

Floyd gives me a warm smile, but it does nothing to erase my doubts. 

"Hati? Would you mind joining us to the baths?"

I immediately shake my head when I hear the word 'bath'. I've been avoiding that place for a good reason. 

I'm already dealing with more stress than I can handle. I don't need the added annoyance of getting murdered for bathing. If people started asking about my tunic again…

*if sex = "male"
    They could see the tattoo. Sure, nothing came of what the doctor and a few others saw during health inspection but I'm sure that was just luck. I do not want to test my luck again.
            
    The Optio saw it. I wonder why he hasn't acted on it. Perhaps he has, behind the scenes. Or maybe Marcus told him not to interfere? Would he do that?
        
*if sex = "female" 
    Every time someone looks at my tunic a lump of something vile forces itself into my throat. The bindings itch my skin but I can bear with it. 
    
    I [i]need[/i] to bear with it.

*page_break
It's a wonder no one's found me out yet. I'm done testing my luck, I can go without a bath.

Besides, from time to time I've bathed in the river. That should be more than enough. Sure, the water is cold and the locals seem to take me for a beggar. If I bathe during the night, however, the water is even colder and the locals take me for a lunatic. 

In the end, I've found myself evading anything bathing-related. As a result, even my own nostrils catch a whiff of something nasty. At first, it took a moment to realize that it's me: I'm the nasty-smelling soldier who hasn't bathed in weeks.

"Hati. To be honest…" Floyd continues. "We have to share the barracks with you. And you… how should I say it…"

Brick steps in: "You stink."'

"Yes, thank you." Floyd nods. "What he said. You indeed smell like you've been dragged through sewers."

*fake_choice
    #Floyd continues: "Sure, you sleep on the top bunk but still..."
        *set top_bunk true
        "…if you shuffle in your sleep, the moving air carries the smell down. It's a bloody assault."
    #Floyd continues: "Since you sleep on the bottom bunk..."
        *set bottom_bunk true
        "…the smell carries upwards. It's been making my nights increasingly intolerable."
        
"Oh, please. It's not that bad." Is it? Perhaps I've just gotten used to it. Well, obviously they should get used to it, too.

"Dragged through sewers after being pissed on," he continues, taking his time to analyze my state of cleanliness. Or lack thereof. "And—"

"Yes. Thank you. I get it. I smell."

"Yes. Indeed. I hope you realize the severity of the situation." He beckons me towards him. "We noticed that you're walking away from the baths."

*fake_choice
    #"I'm not going to take a bath."
        I almost cross my arms to enhance the weight of my words. They can't make me. I could die. They don't know that, sure, and I can't just tell them that, either.
        
        Floyd, however, has other plans. "I knew you'd say that." He turns to Brick. "You know what to do."
        
        Before I can react, Brick has taken two long strides towards me and he hoists me over his shoulder.
        
        "WHAT THE—"
        
        "Don't struggle. I will drop you on your head."
        
        *if build = "heavy"
            How is he even capable of carrying me? What is this!
        *if ((build = "average") or (build = "lithe"))
            "Hey!" I try to shout at him but he just tightens his grip on me.
            
        Floyd shakes his head. "I'm really sorry about this, Hati. This is necessary. We'll be there to look out for you."
        
        "Ugh, fine. I'm coming. Just put me down."
        
        If I die, it's on you.
    #"Fine." I doubt they'd leave me alone. A part of me even wants to spend time with them.
        *set group_friendship +1
        I just need to hope that my luck continues. Besides, there's safety in numbers.
        
        Floyd gives me a relieved smile. "That's great. We were about to drag you in there."
        
        "Huh?" I look at Brick, who nods and stretches his arms, as if he indeed was ready to pick me up.
        
        Floyd shakes his head. "Well! Never mind that. We'll look out for you," he says.
    #"I'm not sure if that's a good idea."
        It's most definitely not a good idea. I could just as well use wet rags to clean myself.
        
        But it seems that the others are not budging on this.
        
        Fine.
        
        I just need to hope that my luck continues. Besides, there's safety in numbers.
        
        Floyd gives me a relieved smile. "That's great. We were about to drag you in there."
        
        "Huh?" I look at Brick, who nods and stretches his arms, as if he indeed was ready to pick me up.
        
        Floyd shakes his head. "Well! Never mind that. We'll look out for you," he says.
    #Sigh and shrug. Fine.
        I just need to hope that my luck continues. Besides, there's safety in numbers.
        
        Floyd gives me a relieved smile. "That's great. We were about to drag you in there."
        
        "Huh?" I look at Brick, who nods and stretches his arms, as if he indeed was ready to pick me up.
        
        Floyd shakes his head. "Well! Never mind that. We'll look out for you," he says.
        
*page_break
After dropping off our armor in the barracks, it's time to head to the baths. The pessimistic part of me is readying itself for death, complaining that I'm taking this too lightly. That I shouldn't go.

Ugh. I'm in constant danger to die, I've grown dull to it.

I'm still half tempted to leave but after Brick gives me a dirty look, I stay on the course.

It's just one bath. I can do this. Keep the tunic on, wash quickly, no chit-chat, leave.

It will be fine.

Everybody else strips naked but me and Kegan. No one utters a word about it, they're already used to it by now. I let out a little sigh of relief.

*if sex = "female"
    The bindings continue to itch and I really hope that I could just take them off. However, it's out of the question.
    
    *fake_choice
        #Even if my breasts aren't on the bigger side, the others could still notice.
            *set breasts "small"
            I'm not going to take any unnecessary risks. The bindings stay on.
        #My breasts are average-sized and the others would notice.
            *set breasts "average"
            The pressure on my chest is immense but the bindings stay on.
        #My breasts are unfortunately quite big and the others would definitely notice.
            *set breasts "big"
            The moment I take the bindings off, I'm found out. 
            
            At times, though, I feel like the pressure is killing me.
    
    There's rash under my arms and the amount of sweat I need to deal with is making me feel like there's a colony of ants under my skin.
    
    I wonder if Niall would be willing to give me a cream of sorts to help me with my skin?
    
    Would he ask? I'm not sure. I just want to get out of these bindings and breathe freely.

My pace is quick as I follow the others to a pool. I need to act with haste.
*page_break

I sink into the pool and start quickly washing myself. I look around, fearing the sight of anyone who could intervene.

*if sex = "male"
    "What's the hurry?" Floyd asks.
    
    I quickly shake my head and lie: "I'm just hungry."
    
    "Oh. It was a tedious march, indeed."
    
    I mutter something and keep washing.
    
*if sex = "female"
    The bindings continue to itch. I really, really wish I could just take everything off and bathe normally. The skin on my chest is like a scab that I can't scratch.
    
    I try to take a deep breath but the pain in my rib makes me almost howl in pain.
    
    "What's wrong?" Floyd asks. 
    
    I shake my head. I can't tell.
    
    I feel his gaze lingering on me. But I can't stop to reassure him, I need to get out of here quickly. I keep washing. Keep wishing I could just take the bindings off.

*page_break
I'm adequately clean. It's time to leave. I start to get out of the pool.

"Wouldn't you like to stay and—" Floyd starts to speak but I can't hear him.

Someone just came into view. Someone who makes my blood turn into ice. He walks towards our pool with no hesitation, his gaze burning a hole on my skin. He's here for me.

The Optio.

*page_break
"Lord Optio." Floyd gets out of the pool with a strained smile on his face. "Could I ask what—"

"Shut up."

"I've been thinking, maggot."

That can't be good. People like him really shouldn't start thinking.

"Why are you always wearing your tunic?"

A lump of something solid creeps into my throat, almost forcing me to gag. Shit.

I knew this would happen. Of course it would be him. 

Before I can answer, Kegan steps towards him. "I am wearing a tunic, too, Lord Optio."

The Optio squints his eyes. "I don't care if you're wearing your mother's dress, you little shit. Shut your mouth when adults are talking." Then, he looks at me, raising his chin.

"Take off your tunic."

"What?" I try to swallow, but my throat is dry.

"There shouldn't be a problem, right?" He starts circling me. "It certainly looks like it's a problem."

The wet tunic hugs my frame, only enhancing my feeling of vulnerability.

My body jerks in surprise when he takes a hold of my arm. He squeezes so tightly I almost shout. 

He leans next to my ear and whispers: "Who are you?"

*fake_choice
    #Yank my hand away from him.
        His hand is left hanging as he leers at me. He looks at me as if he knows. Or he really, really wants to know.
        
        He's going to try and get all the proof he needs. All he needs to do is to take off my tunic.
        
        Then, he's going to kill me. Will he torture me first? Most likely. Will he do it himself?
        
        Certainly.
    #Freeze.
        I don't know what to do. Every part of my body freezes. With my eyes widened I look at the Optio.
        
        A gasp leaves my lips as he takes a hold of my tunic. "Take it off."
        
        "Let go of him!" Floyd's voice rings in the bath house.
        
        I look at Floyd with the Optio still holding onto my tunic. Floyd gives me a reassuring nod, as if he could help.
        
        "Stay back!" The Optio shouts as spit falls on my face.
    #"If you don't let go of me, you will regret it."
        He gives me a cruel smile. "I won't be the one who regrets coming here."
        
        I clench my jaw. What can I do? My hand wanders to the spot where my dagger would be but it's left reaching for nothing. 
        
        The dagger is in the changing room.
        
        The Optio looks at my hand. "Were you planning on killing me?" He shakes his head. "This is more serious than I thought."
    #"Are you coming onto me, Lord Optio? Please, I'm not in the mood."
        My words are light, I even give him a little lopsided smile. But my heart races so fast I fear it's visible through my soaked tunic.
        
        He squints his eyes at me before giving me a cruel smile. "Just take off the tunic or I will."
        
        Floyd takes a step towards us. 
        
        "Don't come any closer."

"Take off your tunic," he says, murderous intent oozing from his words.

*choice
    #"Please, Lord Optio. Not here. What if we took this to the changing rooms?" I purr, imagining myself stabbing him.
        Disgust flashes on his face. He spits on the ground. 
        
        "Do you take me for a fool?"
        
        I almost say yes but realize this is not the time to antagonize him.
        
        However, I'm out of options.
        
        I can't kill him here. I can't take my tunic off.
        
        What can I do?
        *if group_friendship >= 2
            *goto ch5_squad_defense
        *goto ch5_antonia_totherescue
    #Quinn! Where is Quinn?
        *set quinn_trust +1
        $!{q_he} can read my mind. What if ${q_he} can hear me?
        
        What if I shouted loudly enough?
        
        Quinn!
        
        Help me!
        
        The Optio looks at me with a frown. "Why are you looking like that? Shit, you're weird."
        
        I wait to see Quinn to walk towards us.
        
        But there's nothing. $!{q_he}'s not coming.
        *if group_friendship >= 2
            *goto ch5_squad_defense
        *goto ch5_antonia_totherescue
    #"Fuck off. I'm not taking it off." Stand my ground.
        I look him dead in his eyes and curse him off. That's all I can do without my dagger.
        
        He squints at me, halting his movement. "You think you can talk to me like that? Who do you think you are?"
        
        "Try me, you shit," I hiss at him. I will tear him down with my bare hands, if I have to.
        *if group_friendship >= 2
            *goto ch5_squad_defense
        *goto ch5_antonia_totherescue
    #"I will tell the Centurion that you're harassing me." Where is that idiot when I actually need him?
        *set marcus_trust +1
        Saying his name does nothing to make him hesitate. 
        
        "Maybe he doesn't know who you really are…," he mutters to himself, his gaze lingering on my tunic.
        
        "He will kill you if you do something to me." Will he? I don't know. 
        
        "Let's see about that." Suddenly, he yanks at my tunic. 
        *if group_friendship >= 2
            *goto ch5_squad_defense
        *goto ch5_antonia_totherescue
    #Remain silent and still. I don't know what to do. I'm terrified.
        I merely look at him. I don't know what to do.
        
        I can't do anything. All I can do is watch the situation unfold.
        *goto ch5_squad_defense
    #Look at Floyd, Pec, and Kegan.
        I look at my men with a pleading gaze. Please, help me. 
        
        Floyd gives me a quick, determined nod.
        *goto ch5_squad_defense

*label ch5_squad_defense
*page_break
"Lord Optio, what is the meaning of this?" Floyd asks, making the Optio take a step back. He slips between us, blocking me from the Optio. "Are you going around the bath demanding men to strip for you?"
        
The Optio's ears flush deep red. "Move aside."
        
Floyd gulps but he stays still. Then, Pec joins his side. "You really should take your kinks elsewhere, Lord Optio. We were just taking a bath." 

My eyes widen at their loyalty. They could be killed for this. No, they [i]will[/i] be killed for this. They would die for defending me. Why? 

Kegan takes a step towards us, too. But, before he has the chance join the defense, a loud thump halts any movement. 
        
Floyd lies on the ground, groaning. The Optio stands over him with a sneer on his face. "You will all be flogged for this!"
*goto ch5_antonia_totherescue

*label ch5_antonia_totherescue
"What is going on here?" A familiar, high, and sternly demanding voice disturbs the dire situation. That couldn't be.

Antonia.
*page_break
She stands with her hands on her tiny hips, her face a mess of wrinkles as she sneers at the high-ranking man like she owns the place.

The Optio glances at her before rolling his eyes. "Piss off. This doesn't concern you." However, his gaze is darting all over the place.

Antonia merely puffs her little chest at his words and puts more emphasis on her next question: "I asked, what is going on here?"

The Optio closes his eyes, clearly pondering on the possible repercussions he might have if he told the niece of the Centurion off. She's the grand-daughter of the Legate. He knows he's outmatched.

Antonia smells his hesitation and asks just the right question: "Do you want to take this to my uncle?"

"No." The Optio finally says with a succumbing sigh. He's yielding.

He gives me a dirty look and whispers: "You know this is not the end." 

With these words lingering behind him, he leaves. 

Antonia frowns after the fleeing Optio before turning to me. Her features light up, her eyes squint in delight.

"I thought you needed help."

*fake_choice
    #Hug her.
        A surge of relief washes through me and I take the child into my embrace. She squeaks in surprise before starting to giggle uncontrollably against my tunic. "Hati, that tickles!"
        
        Her laughter is infectious and I start laughing with her. "I'm sorry!" I say as laughter lingers on my words, still hugging her little frame in gratitude. "And thank you." I let her go.
        
        She takes a grateful inhale before shaking her head and waving her arm like it's nothing. Like she didn't just save my life. "Don't worry about it!"
        *if cockpunch
            "I did say that I would help you if you needed me."
    #Thank her.
        She shakes her head and waves her arm like it's nothing. Like she didn't just save my life. "Don't worry about it!"
        *if cockpunch
            "I did say that I would help you if you needed me."
    #Nod.
        She gives me a solemn nod in return, mimicking my stern features.
        
        "Hati. She saved your life," Floyd says. "Thank you, little girl." He beams at Antonia. "Did you say that you're our Centurion's niece?"
        
        "Yes," she says with a quick bob of her head. "I will tell him about that nasty man."
    #Remain silent.
        "Hati. She saved your life," Floyd says. "Thank you, little girl." He beams at Antonia. "Did you say that you're our Centurion's niece?"
        
        "Yes," she says with a quick bob of her head. "I will tell him about that nasty man."

*page_break
Just now, I realize how out of place she looks in the bath meant for soldiers. She's also fully dressed, which means she's not here for a bath. "What are you doing here?"

"I followed Robus." She smiles and, as if just now remembering what she came to do, she looks around with a concerned look on her face. "We were playing and she ran here."

Then, a deep, singular bark draws our attention to a dog trotting towards us. 

"Robus!" Antonia claps her hands.

*fake_choice
    #Greet Robus.
        I open my palm to her and she nibbles at it, trying to get me to pet her.
        
        And, as I'm asked to, I giver her a pat on her head. She puts her ears back and closes her eyes, clearly enjoying herself.
        
        "Did you sense that I'm in danger, girl?"
        
        "Woo woo," she says and starts nuzzling her soft cheek against my thigh. 
        
        There's a smile ringing through Floyd's words as he says: "I didn't realize you had this many guardians at your disposal, Hati."
        
        "I'm popular with the little ones."
        
        Antonia nods her head. "Robus and I really like Hati."
        
        Floyd smiles. "That's lovely, I like Hati, too."
        
        The kindness and warmth I'm surrounded with is almost making me dizzy, at least after what I just went through. I step away from Robus and try to calm my breathing.
        
        I'm safe. For now.
    #Don't greet her.
        
*page_break
Antonia frowns her little face. "Why did the Optio bother you?"

I shake my head. "I shouldn't have come here. I can't use the baths," I berate myself, almost ignoring Antonia. I'm still rattled and very much annoyed.

"Oh." She ponders on my words. "Well, do you want to use our baths?"

"Yours, as in…"

"Mama and I are staying with uncle while we're here. You could use our bath," she says again, this time with a look that says 'Of course you want to use our bath, why am I even asking'. 

Using Marcus's bath to avoid attention? I'm not sure if I like the sound of that.

*fake_choice
    #"I would like that, thank you."
        *set rude -1
        *set marcus_bath true
        I give her a smile, one that is well-deserved. She saved me. I'm not sure if she understands the severity of the situation she found me in. 
        
        It might be better if she doesn't know.
        
        She gives me a wide smile back. It reveals a freshly fallen tooth, in its place only a hole. She doesn't let it bother her smile. That's a good characteristic.
    #"Are you sure your mother doesn't mind? Or your uncle?" I suppose I could say yes...
        *set marcus_bath true
        Emphasis on her uncle. I'm not sure how I'd feel about it. I might run into his stupid, grinning face on the way there. That would be highly unpleasant.
        
        "Of course not! It's not the first time I've invited someone to use our stuff."
        
        For some reason, that doesn't make me feel better. But, at least her mother has gotten used to strangers barging into their house. She shouldn't be too surprised to see me there.
        
        At least that's something.
        
        "And my uncle… well, who cares what he thinks."
        
        "I couldn't have said it better myself."
        
        She nods and gives me a wide smile. It reveals a freshly fallen tooth, in its place only a hole. She doesn't let it bother her smile. That's a good characteristic.
    #"No, thank you." I won't use Marcus's bath.
        I would rather bathe in the river. 
        
        Yes, it's cold and it's almost ridiculous. But what would be more ridiculous is sharing bath with Marcus, of all people. 
        
        So, no. No, thank you.
        
        She gives me a little pout. "Are you sure?"
        
        "I am sure." It's a nice enough gesture. So, I give her a small smile. She did save me from certain death. I'm not sure if she understands that.

*page_break
Even if the most acute danger is over, worry and fear still linger over me.

The Optio won't let this slide. 

He went to see Marcus, I'm sure of it.

I need to get there, too.

So, with a quick farewell, I start walking towards the changing room.

Floyd asks after me but I ignore him. I need to hurry.

*page_break
The shouts of the Optio echo through the hallway. 

"They disobeyed a direct order, Lord Centurion! I have already scheduled for their flogging."

A wave of cold flushes through me. The act of flogging is nearly a death-sentence, depending on the number of beatings. However, there's something that shudders me to my core even more than that: every victim is forced to be fully naked. For others, it acts as a extra humiliation. For me, however…

I need to think of something.

*fake_choice
    #I'm rattled and afraid but still will myself to be calm and knock on the door.
        *set disciplined +1
        I want to barge in, I want to set the facts straight here and now.
        
        However, I can't. The voice of my father tells me to calm down.
        
        Calm down and act like nothing is wrong. 
        
        "What is it?" Marcus asks, irritation seeping from his words. 
        
        I open the door with my head held high. 
        
        Marcus sits behind his desk with an unreadable expression. He barely takes a look at me and says: "I was expecting you."
        
        Why does he sound so emotionless? A sense of dread creeps into my heart. This doesn't look good.
        
        Just now I realize that there's a third person in the room. A Centurion, by the looks of it. He holds a similar-looking helmet under his armpit and regards me with a sneer. 
        
        I quickly bite my lip.
        
        If barged in without knocking, I would only look more deserving of a flogging.
    #Keep calm and knock on the door.
        *set disciplined +2
        The voice of my father tells me to calm down and act like nothing is wrong. I will do just that. Nothing good comes out of acting too rashly right now.
        
        "What is it?" Marcus asks, irritation seeping from his words. 
        
        I open the door with my head held high. 
        
        Marcus sits behind his desk with an unreadable expression. He barely takes a look at me and says: "I was expecting you."
        
        Why does he sound so emotionless? A sense of dread creeps into my heart. This doesn't look good.
        
        Just now I realize that there's a third person in the room. A Centurion, by the looks of it. He holds a similar-looking helmet under his armpit and regards me with a sneer. 
        
        I quickly bite my lip.
        
        If barged in without knocking, I would only look more deserving of a flogging.
    #Just barge into the office, my life is in danger!
        *set disciplined -1
        *set ch5_obey_failure true
        I don't have time to think. I need to act.
        
        "Lord Centurion!" I shout as I swing the door wide open and step into the room unannounced. 
        
        Marcus shakes his head with a frown, rubbing his temple. 
        
        Just now I realize that there's a third person in the room. A Centurion, by the looks of it. He holds a similar-looking helmet under his armpit and regards me with a sneer
            
        He gives me a cold look. "What is the meaning of this? Is this the soldier who disobeyed you?"
        
        The Optio nods quickly. "That's the one."
        
        Oh, crap. This doesn't bode well. Now I only look more deserving of a flogging.

*page_break
The Optio points at me with a furious look on his face. "He just walked in as if owning the place! What is the meaning of this?" His hand twiddles the rod resting on his hips. It must be a reflex, he's not just going to beat me in front of Marcus and the other Centurion. 

Right? 

Marcus would stop that. Maybe.

Marcus sighs, shakes his head, and silences the Optio with a small hand gesture. "I have a growing headache," he mutters behind his breath, massaging his temple. The Optio is about to say something but decides against it after Marcus gives him a deadly glare.
 
The man beside Marcus is almost the same rank as him. He stands as if his spine was replaced by a pole, his eyes pierce me like knives.
    
The wrinkles on his face is a telltale of a man who rarely smiles. 
    
This will complicate things. Marcus is going to have to play more by the books. He can't just let me off the hook, like he usually does. He might be one of those who want to lead by example.

That would be bad. For me.
*page_break

"So," Marcus starts and looks at me with his brow raised. "You refused to take the tunic off in the baths? Even though your Optio clearly told you to take it off?"

"Yes, Lord Centurion." He knows why I had to do that.  

Optio points at my tunic. "Isn't that weird? Why does he—"

"Zoilus, if you open your mouth again, I will feed you to Robus."

The other Centurion gives Zoilus a slightly puzzled frown. "Why did you want him to take off his tunic, anyway?"

"Well—," the Optio starts.

*fake_choice
    #This is my chance. "Lord Centurions, he was trying to assault me." In the army, that's grounds for execution.
        *set zoilus_the_assaulter true
        The Optio's eyes widen at my accusation.
        
        The Centurions look at each other before Marcus asks me: "Is that true?"
        
        I nod. "Yes, Lord Centurion. He tried rip my clothes to assault me."
        
        The Optio shouts: "In the middle of a public bath?! That's ludicrous!"
        
        "I don't claim to know what went through his mind, Lord Centurions." I bow my head and look at the floor.
        
        The Optio says, his tone slightly panicked: "Lord Centurions, just order him to take off his tunic to see—"
        
        "Silence."
    #Remain silent. I don't know if me saying something would only lead to more trouble.
        *set disciplined +1
        I bite my lip. I don't know what to do. If I stay quiet, perhaps they'd see that the Optio is the more chaotic and deranged one in this situation. 
        
        So, I choose silence. And hope that it won't get me killed.
        
        "I have a hunch that he has something to hide, my Lords," The Optio says.
        
        "What something?" The other Centurion asks.
        
        Marcus cuts in: "Zoilus, you need to take these things to me."
        
        "Yes, Lord Centurion…"
        
        Hope makes me perk up. He stopped Zoilus from spouting out his allegations. Perhaps he is on my side.
    #I'm certain Marcus won't have me flogged. I don't need to say anything. 
        *set marcus_trust +1
        Placing so much trust on that creature of a man is a risky move, but everything that's happened so far tells me that he's interested in keeping me alive.
        
        I dearly hope that my instincts are right.
        
        So, I merely look at Marcus. I do so subtly, so the other Centurion wouldn't think much of it. My gaze is pleading: 'Do something'. I will myself not to add the usual 'or else' threat into it; this is one of those times I need to act like he's got the upper hand. 
        
        Well, he does have it. As much as I hate to admit it.
               
        "I have a hunch that he has something to hide, my Lords," The Optio says.
        
        "What something?" The other Centurion asks.
        
        Marcus cuts in: "Zoilus, you need to take these things to me."
        
        "Yes, Lord Centurion…"
        
        Hope makes me perk up. He stopped Zoilus from spouting out his allegations. Perhaps he is on my side.

*page_break
Marcus sighs again, and an uncomfortable thought sneaks into the back of my mind: What if he's considering it? The flogging? He saved me once already, what if he's starting to get bored with me?

*if zoilus_the_assaulter
    The other Centurion looks at me pointedly. "Your Optio's word weighs more heavily than his."
    
*if not(zoilus_the_assaulter)
    The other Centurion looks at me pointedly. "At least he's docile. As he should be."
    
*fake_choice
    #Throw the other Centurion a dirty look.
        *set disciplined -5
        *set ch5_obey_failure true
        I can't help myself. 
        
        His gaze hardens.
        
        "Marcellus. I wouldn't trust anything that soldier says."
        
        With a frown, Marcus looks at me and shakes his head. Oh crap.
        
        I made the matters worse.
    #Remain silent.
        *set disciplined +2

I just realize that my heart is pounding loudly in my chest.

*if marcus_killer
    I did threaten to kill Marcus just the other day. This is his opportunity to get rid of me completely. This is his opportunity to have his revenge.
    
*if not(marcus_killer)
    Would he really do it?
    
He knows who I am, what I came here to do. He could easily get rid of me.
*page_break
The silence in the room is weighing heavy on my chest.

Why isn't he saying anything? A lone, cold bead of sweat creeps its way from my hairline towards my jawline.  

"So," he finally begins. The single word is followed by yet another moment of silence.

*fake_choice
    #"So what, Lord Centurion?" Just flog me already if that's your thing, I don't have all day.
        *set disciplined -5
        *set ch5_obey_failure true
        Marcus gives me tiny raise of his eyebrow and shakes his head as if saying: 'This is not the best time for that attitude'. It's there mixed with 'are you trying to get yourself killed?' musings.
        
        Maybe I am. That would explain, well, everything I've done so far.
        
        The other Centurion scoffs. "This is ridiculous. Why are you even considering if that man needs a flogging? He's an undisciplined bastard."        
    #Remain silent and wait for him to speak.
        *set disciplined +1
        I steel myself and keep my chin up. I won't look my superiors into their eyes, the other Centurion might take it as an act of rebellion. I just wait for the judgment.
    #I'm starting to panic.
        *set disciplined -2
        My gaze darts from one furniture to another. From one Centurion to another. To the Optio. To every one of these men who could have me killed in a heartbeat without any consequences.
        
        My breathing is shallow and quick.
        
        'Deep breaths', father used to say. I can't.
        
        *if sex = "female"
            I physically can't take deep breaths because of the bindings, I can't—
    #Where is Quinn? $!{q_he} could help me.
        *set quinn_trust +1
        And to do what? 
        
        $!{q_he}'s saved me so many times before, why wouldn't ${q_he} do it now?
        
        So, I hold my breath and listen to any sounds that would implicate that ${q_he}'s here. However, only the sounds of the Optio's agitated heavy breathing fills the room. 

Marcus turns his gaze to me, his features wholly unreadable.

Cold.

Dread washes over me. He could do it. He could have me flogged.

*if marcus_killer_samhain
    "It seems that I have no other choice than to—"

*page_break "Wait just a moment!"
The door slams as someone barges in. I turn to look at the intruder.

"Floyd?"

*page_break
"It was me!" Floyd shouts. "I was the one who disobeyed Lord Optio. I'm the one who deserves the punishment." He just seems to realize there are more officers in the room than usual and, as an afterthought, adds: "Lord Centurions. Lord Optio."

*fake_choice
    #Order him to leave with my gaze.
        I try to look him in the eyes and order him to leave. I can handle this on my own. I'm not having anyone's death on my conscious.
        
        However, he refuses to look at me.
        
        Stupid man! You have children and a wife, leave!
        
        He doesn't. He looks at the superior officers with conviction, with his chin held up high, his mind made up.
    #He's here to save me!
        Relief washes over me. Thank the Twins. He's here to save me.
    #Just see how the events unfold.
    #Why would he do this?
        I'm left puzzled over his appearance. Why would he try to defend me?
        
        *if group_friendship > 2
            I've grown to like him, yet… This is not what I expected from him.
        *if group_friendship < 2
            Especially since I haven't even been friends with him. I should be nothing to him.
            
            Yet here he is. Endangering his life. For me.

*page_break
*if zoilus_the_assaulter
    Marcus raises his brow at Floyd. "So, you witnessed what's claimed that happened?"
    
    Floyd gives me a quick glance before standing up straight. "The Optio tried to rip Hati's tunic off. I stepped in and I should be punished."
    
    "If that is indeed what happened, it was your right to do so."
    
    Floyd nods, clearly still unsure of the implications.
    
    *page_break Marcus sighs.
    "Optio?" Marcus looks at the Optio.
    
    The Optio knows not to start rambling. Instead, he steps into view with his head down.
    
    "What do you say of the charges?"
    
    "I did not—"
    
    He blocks any excuses with his hand. "We have a witness."
    
    Floyd raises his hand to ask for permission to speak. Once given, he says: "We have multiple witnesses, Lord Centurion. Our whole contubernium saw what happened."
    
    Hope rises within me. Perhaps I can survive this with no one getting hurt.
    *page_break
    
    *if ch5_obey_failure
        "Marcellus," the other Centurion says and beckons Marcus to follow him to the hallway. The look on his face makes my stomach drop.
        
        This can't be good.
        
        The room is silent, save for the Optio's heavy breathing.
        
        I turn to look at Floyd, who gives me a quick nod of reassurance and a little smile to accompany it. "Don't worry," he whispers.
        
        Then, the door opens. Marcus doesn't look at me when he walks past me.
        
        That's not a good sign.
        
        Marcus sits on his chair and sighs. "Floyd. 40 lashes."
        
        40? He could die. The Roman lash is meant to tear off the flesh.
    
        Floyd merely nods at the news. Then, he gives me a little smile. 
        *goto floyd_flogging
    
    *if not(ch5_obey_failure)
        *set ch5_no_flogging true
        Marcus sighs. "Dismissed, all of you."
        
        "But—" The Optio starts.
        
        Marcus shoots him with a deadly glare and the Optio falls silent. "I will deal with you later," he mutters to the Optio.
        *goto ch5_marcus_bath
        
*if not(zoilus_the_assaulter)
    "It was me who disobeyed the orders. I stepped in." 
    
    Marcus nods. "We'll flog you, then," he says with a shrug. "40 lashes."
    
    40? He could die. The Roman lash is meant to tear off the flesh.
    
    Floyd merely nods at the news. Then, he gives me a little smile. 
    *goto floyd_flogging

*label floyd_flogging
*fake_choice
    #"No!" Floyd helped me. He doesn't deserve to be flogged for this.
        *set floyd_nooo true
        *set disciplined -1
        The other Centurion roars: "You dare to interrupt?" He turns to Marcus: "Are you [i]sure[/i] you don't want to flog him, as well? I wouldn't hesitate—"
        
        Marcus raises his hand with a shake of his head. "One is enough for today."
        
        The other Centurion nods and doesn't argue back, even if he clearly wants to.
        
        Floyd places his hand on my shoulder. Instinctively, I look at him. His eyes are too kind, he looks determined as he gives me a curt nod. 'Don't,' he says without words.
        
        *if group_friendship >= 2
            He is my friend. He's going to suffer because of me. He could die because of me.
        *if group_friendship < 2
            We haven't really seen eye to eye, I haven't talked to him or the others that much. But it doesn't change the fact that he shouldn't suffer for something I did. He helped me. He…
            
        Floyd shakes his head again before turning to look at the officers.
    #Remain silent. This is not right but I doubt my shouting would make it better.
        *set floyd_nooo true
        *set disciplined +1
        I squeeze my fists into two tight, trembling balls. There's not much I can do to make this better. They have already made their decision.
        
        Floyd places his hand on my shoulder. Instinctively, I look at him. His eyes are too kind, he looks determined as he gives me a curt nod. 'Don't,' he says without words.
        
        *if group_friendship >= 2
            He is my friend. He's going to suffer because of me. He could die because of me.
        *if group_friendship < 2
            We haven't really seen eye to eye, I haven't talked to him or the others that much. But it doesn't change the fact that he shouldn't suffer for something I did. He helped me. He…
            
        Then, two soldiers take Floyd by his shoulders.
        
        "Oh, already?" Floyd asks. "Well, might as well get it over with…" He gives me a little goofy grin, as if it would make me feel better. "Please 
    #That would solve my problem. Also, Floyd seemed willing to receive the punishment in my stead. I act sad and shocked.
        *set manipulative +2
        *set ruthless +5
        I nod and try to look sad. I shouldn't overdo it, though.
        
        Floyd gives me another small smile accompanied with a nod. 'Don't worry', he says without words.
        
        Don't worry, Floyd, I'm not worrying. I still give him a little smile and a nod. Still, I hope he survives from his flogging.
        
        It would be a nasty way to go.
    #I don't really care that much if Floyd gets flogged for me. The man seems to want that.
        *set ruthless +5
        I almost shrug at the news but manage to stop myself in time. Instead, I remain expressionless. It's better that way.
        
        Floyd seems to misread my silence as shock. He furrows his brows and gives me a small nod. As if I needed him to reassure me that he's doing this of his own volition.
        
        I nod back at him.
    #"Please, Lord Centurion. Flog me, instead."
        *set floyd_nooo true
        *set ch5_martyr true
        Marcus frowns at my words. He looks at me as if I've lost my mind. Both of us know what it would mean to me.
        
        I'm ready to accept it. I raise my chin to let him know that I'm serious. No innocent man will die or be tortured for me. That would be shameful. Father would be disappointed. I will rather die.
        
        The other Centurion shrugs. "Well, if he wants to—"
        
        "No."
        
        "Why not? The boy wants to be flogged."
        
        "We are not handing out punishments on the basis of someone wanting them."
        
        The Centurion purses his lips together and remains silent.
        
        "I hate martyrs," Marcus mutters to himself and looks at Floyd.

*page_break
"Dismissed," Marcus says to the other Centurion and the Optio. Me and Floyd are left to the room. 

"Don't worry about it," Floyd says to me. His face is pale but still he smiles. It's as if he's comforting a child in turmoil. "It's just 40 lashes. At least they didn't sew me into a sack and throw me in a river with a monkey, a dog, and a snake."

Is that an actual punishment?

Stupid, cruel Romans.

"And a rooster," Marcus adds without a smile.

"Oh, right. Poor rooster, too. That's one crowded sack."

"This is not funny," I say with a frown. 

Floyd shrugs, his features turning more serious. "If something happens to me… could you come up with something else that ended me? More heroic. I don't want my wife and children to think their father left like this."

Before I can answer, Marcus says: "We will tell your family that a Germanic tribe swooped in and you went down fighting."

"Thank you."

Then, a few soldiers come to escort Floyd away. He gives me one last glance of goodbye and then he's gone.

"Is he going to get flogged right away?"

Marcus nods.

*page_break
*if floyd_nooo
    The thought of Floyd being dragged to be flogged makes my stomach churn.
    
    Marcus looks at me in deep thought.
    *if ch5_martyr
        Finally, he says: "That was stupid."
        
        "What part, exactly?"
        
        "You almost getting yourself killed for him."
        
        I clench my jaw and shake my head. "Not as stupid as dragging an innocent man to be flogged."
        
        "Perhaps," Marcus says and sighs.
        
    I ask: "Can't I go and see? Perhaps it would make it better for him."
    
    "You want to see him being flogged? No."
    
    "But what if he needs—"
    
    "I said no."
    
    I purse my lips. Why is he making that decision for me?
    
    *fake_choice
        #"I'm going."
            *set disciplined -4
            Before I can leave, takes a hold of my shoulder. "Are you an idiot?"
            
            "I—"
            
            "Both of the men who wanted you to be flogged with Floyd are there. You will share his fate."
            
            "But—"
            
            He looks at me as if I'm an idiot. Perhaps I am. I just…
            
            The thought of him being there alone. The thought of him dying because of me…
            
            Marcus shakes his head. "He won't die. He has too much to lose."
            
            "His wife and children?" The thought churns my stomach even more. Perhaps Marcus is right… Perhaps the thought of them keeps him alive.
            
            So, with a deep sigh, I sit down on his couch. I bury my face in my hands. This is too much.
            
            "We will get him to see the doctor after the flogging," he tries to console me. At least, I think that's what he's doing.
        #Fine. I couldn't bear to watch it, anyway.
            *set ruthless -2
            I bite my lip and look away. The thought of him being there alone makes my mouth dry. The thought of him dying because of me…
            
            Marcus shakes his head. "He won't die. He has too much to lose."
            
            "His wife and children?" The thought churns my stomach even more. Perhaps Marcus is right… Perhaps the thought of them keeps him alive.
            
            So, with a deep sigh, I sit down on his couch. I bury my face in my hands. This is too much.
            
            "We will get him to see the doctor after the flogging," he tries to console me. At least, I think that's what he's doing
    *goto ch5_marcus_bath

*if not(floyd_nooo)
    Marcus sighs behind his desk. "It's good that you're not overly emotional about this."
    *fake_choice
        #I'm just so happy that I'm still alive.
            Relief washes over me and I close my eyes.
            
            Another close one. How many of these can I survive? It's as if there's someone looking after me.
            
            "Are you alright?" Marcus asks.
            
            I nod. As fine as I can be, I suppose.
        #"I've ceased to care," I say in monotone voice.
            "About your life? Or the others'?" He asks, a slight frown forming on his face.
            
            Both, probably. 
            
            "That's unfortunate."
        #Shrug.
            I'm just happy that I survived. That was a close one. 
            
            Again.
        #"That sounds condescending."
            "You can choose to interpret it that way, if you want to." He shakes his head.
                
*label ch5_marcus_bath
*page_break
"What are you going to do about the Optio?" I ask.

"I don't know." He sighs again and starts rubbing his temples.

Silence.

*if floyd_nooo
    "Is Floyd [i]actually[/i] going to get flogged?" I know he is. But… maybe it was just for the show. Maybe he was actually dragged somewhere else.
    
    A shadow crosses Marcus's face. He raises his chin and says curtly: "Yes."
    
    A surge of regurgitation punches my stomach. I wonder if he's already being flogged?
    
    Marcus purses his lips. "It's unfortunate."
    
    "Then, why…"
    
    "Would you prefer it to be you?"
    
    *if ch5_martyr
        "I already said yes."
        
        "Right, you did." He almost rolls his eyes.
        
    *if not(ch5_martyr) 
        "No…" I'm not sure. Why did it have to be anyone? How could he do that?
        
        He shakes his head and sighs. "It is what it is."
    
*page_break
"It's not safe for you to continue using the public baths," Marcus says and looks at me expectantly.
        
*if marcus_bath
    "Antonia told me that I could use your bath."
    
    "Oh. She did?" He raises his brow at me. "And you're just fine with that plan?"
    
    Shrug.
    
    "Pfft. I wouldn't even have suggested that." He studies me. "You could see me naked, you know. If you stumbled in at the wrong time."
    
    *fake_choice
        #"A chance to see you naked again and judge your lacking equipment? How could I refuse."
            He clears his throat and frowns. "Lacking what now?"
            
            "You heard what I said."
            
            He squints his eyes.
            
            I squint my eyes back at him.
            
            He sighs. "Please let me know when you're coming, I'll make sure I'm not there."
            
            "I definitely will."
        #"Why would I enter the baths if I knew you were there?"
            He shrugs. "Perhaps you're a pervert."
            
            I close my eyes and sigh. "I can assure you, I will ask your servants and turn on my heels and leave if you're there."
            
            His pout makes me want to reconsider. Perhaps I should ask Niall? I'm not sure.
            
            I just really want to bathe without fearing for my life. So, this will have to do.
        #Shrug. I just want to bathe without fearing for my life.
            Besides, he already knows who I am. It would be actually a relaxing bath. I wouldn't have to worry that he'd find out.
            
            *if sex = "female"
                The itching underneath my bindings make me bite my lip. I want nothing more than to take them off and wash myself.

*if not(marcus_bath)
    "Would you like to use Niall's?"
    
    "Niall's bath? What would Niall say?"
    
    He shrugs. "He doesn't mind."
    
    *fake_choice
        #"Sure. That could work."*
            *set niall_bath true
            There's no way he'd bother me in the bath, at least. He'd probably avoid being at home altogether while I'm there.
            
            Good. I need privacy.
            
            *if sex = "female"
                The itching underneath my bindings make me bite my lip. I want nothing more than to take them off and wash myself.
        #"No."
            Marcus nods. "Do you think you'll find somewhere else to bathe?"
            
            I shrug. The river might do, if there's nothing else. I will never step my foot in the public bath ever again.
            
The conversation dies out.
*choice
    #I'm still rattled by everything that happened.
        *goto ch5_marcus_you_ok?
    #I just want to leave and I plan on telling him so.
        *set disciplined -1
        I'm too tired. I just want to leave. "I should go."
        
        He nods, clearly not minding the lack of military decorum. "Dismissed."
        *page_break
        *goto ch5_camilla_bath
    #Wait for him to let me leave.
        *set disciplined +1
        Marcus looks at me with a raised brow. "What are you standing there?"
        
        "Am I dismissed?"
        
        "Sure, go." He waves me off.
        *page_break
        *goto ch5_bath?

*label ch5_marcus_you_ok?
I take another deep breath, trying to calm myself.

"You look ill," Marcus states.

*fake_choice
    #"Well, you almost had me flogged."
        He bites his lip and creases his brows. "I didn't."

        *if marcus_killer_samhain
            "You didn't even consider it?"
            
            "What does it matter now?"
            
            "It matters."
            
            "You tried to kill me just the other day."
            
            "Well, I didn't. You're still here." Unfortunately.
            
            He raises his brows as if to say: 'So are you.'
            
            Hm. True enough.
        *if not(marcus_killer_samhain)
            I frown. "Are you sure you didn't?"
            
            "I'm quite sure."
            
            "Why?"
            
            "Why I didn't? Would you have liked to be flogged?"
            
            "No, of course not, I just—"
            
            "You're here. Unflogged and alive. Let's just move on."
            
        So, I just nod. I'm too tired to argue, anyway. The day has drained me and I just want to go to sleep. 
        
        Marcus sighs. "Go to sleep. That's an order."
        
        He's ordering me around, that's nothing new. However, this time I don't mind obeying. So, I leave.
        *page_break
    *selectable_if (floyd_nooo) #"I can't stop thinking about Floyd."
        The thought makes me sick to my stomach. I fear I might throw up any moment now.
        
        "Please don't, ugh—" Marcus starts searching for something. Then, he brings me a bucket to puke in.
        
        How considerate. He just didn't want me to stain his floor. Still, I take the bucket and close my eyes.
        
        "Take deep breaths," he says with a frown. 
        
        It's still unclear if he's worried for me or worried for his floor. Perhaps it doesn't matter. So, I close my eyes and obey him: I start taking deep breaths.
        
        The nausea starts to subside and I give the bucket back to him. He eyes me critically, unsure if he should take the bucket just yet.
        
        "Are you sure?"
        
        I nod. "I'm fine."
        
        "You're pale as a ghost."
        
        "Oh." Makes sense. I feel like crap. Floyd is feeling a thousand times worse, though. I frown.
        
        Marcus shakes his head. "Don't think about him. He's going through it whether you worry about it or not. Just think about something else."
        
        "Like what?"
        
        "Like… Like your mission. Right? Think about how much you want to kill me. That should make you feel better."
        
        It doesn't. But I suppose I appreciate the sentiment, however odd the situation may be.
        
        Marcus sighs. "Go to sleep. That's an order."
        
        He's ordering me around, that's nothing new. However, this time I don't mind obeying. So, I leave.
        *page_break
    #Remain silent.
        I don't want to talk. 
        
        *if floyd_nooo
            The vision of Floyd being flogged makes me sick to my stomach.
            
        *if not(floyd_nooo)
            There's really nothing to talk about. I just need to get over my initial shock.
            
        The day has drained me and I just want to go to sleep. So, I just let out a deep sigh. 
        
        "You look like shit."
        
        Yes. Thank you.
        
        "Go to sleep. That's an order." He waves me off. And I obey. It's been a long day.
        *page_break

*label ch5_bath?
*if niall_bath
    *goto ch5_aftermath
*if marcus_bath
    *goto ch5_aftermath
*else
    *goto ch5_camilla_bath

*label ch5_camilla_bath
Just when I get out of the building, a woman catches my eye.

Camilla. Her cloak hides her intricate wig. It looks like she's been expecting me.

Before I can ask, she speaks: "Antonia told me what happened."

I nod. Which part? 

"You need a place to bathe," she helpfully elaborates. She continues, ignoring my non-answers: "Tinsae has one. Or…" She straightens her posture, as if the next words are difficult for her. "You can use mine."

Oh? That's weirdly nice of her.

…What is her aim?

*choice
    #"I will ask Tinsae."
        *set tinsae_bath true
        She nods. "I'm sure she will approve." With these words, she leaves.
        *goto ch5_aftermath
    #"Can I really use your bath?"
        *set camilla_bath true
        "I wouldn't have offered if you couldn't," she sighs and looks around. "Stop shouting."
        
        I purse my lips, almost retorting back but barely managing to remain silent. I wasn't shouting.
        
        "I will contact you later." With these words, she leaves.
        *goto ch5_aftermath
    *comment siirtymäkohtaus paremmaksi
    #"I'd rather keep bathing in the river."
        *set quinn_bath true
        "In the… river?" She raises her brow. 
        
        When I give no sign of being nothing but serious, she nods. "Suit yourself, barbarian." With these words, she leaves.
        *goto ch5_quinn_bath

*label ch5_quinn_bath
*page_break
"In a river, huh?" Quinn's voice almost makes me jump but I'm strangely used to ${q_him} lurking about and almost causing me a heart attack. I turn to ${q_him} and ${q_he} grins. "I know something better."

"There is this hot spring I know of. It's not that far but it's hidden."

"When did you find it?" I frown, not as happy about the news as ${q_he} clearly expected.

"Um, a couple of weeks ago."

"A couple of…" I take a deep breath and ask through my teeth: "Why didn't you tell me about it sooner?"

$!{q_his} mouth is left hanging open mid-sentence. "I, uh… Didn't think."

"I've been freezing in the river for weeks or getting myself killed. And you knew of a hot spring?" 

$!{q_he} tries to smile but I look at ${q_him} with little to no trace of joviality in me. 

*if sex = "female"
    "I could've taken the bindings off, too." My ribcage weeps at the thought.
    
    $!{q_he} grimaces. "Oh, right." $!{q_he} glances at my chest. "I really didn't think. I'm sorry."

*if sex = "male" 
    $!{q_he} grimaces. "I'm sorry. I was going to tell you. I forgot."

I sigh and shake my head. I suppose it's better late than never.

Quinn sighs in relief. "I'll show you the place soon enough. We might be followed if we go there now."

*goto ch5_aftermath
*label ch5_aftermath

*if ch5_no_flogging
    *comment
    *goto_scene chapter5_dates ch5_dates 
*if not(ch5_no_flogging)
    Once I left the officers' building, there were still remnants of someone screaming in the distance.

    Was it Floyd?

    Most likely.

    Should I go and see him now that the torture seems to be over?

    *choice
        #Yes, I'll go see him.
            *set ch5_floyd_see true
            *goto ch5_floyd
        #No, that won't be necessary.
            *goto_scene chapter5_dates ch5_dates 

*label ch5_floyd
The doctor gives me a little nod as I walk past him to see the room where Floyd is. 

He's lying on his stomach without his tunic. His back is wrapped in fresh bandages and there are pools of blood already forming in the cloths.

"Floyd—" I start, not sure what I should even say.

He doesn't respond. He must be sleeping. His battered back moves franticly.

"Hati? Is that you?" A groan.

"Yes…" I walk toward him, unsure if I should. I caused this. It was me who made him like this.

*fake_choice
    #No. It was the Romans.
        I shake my head. It was them. None of this would have happened if it wasn't for those cruel Romans and their barbaric customs.
        
        He's just another victim of the Romans.
        
        Floyd smiles when he sees me.
    #No. It was Marcus.
        *set marcus_floyd_blame true
        Marcus is the one who ordered this to happen. He's to blame.
        
        He's the reason for everything bad happening to me.
        
        Floyd smiles when he sees me.
    #No. It was the Optio.
        He's the one who started this whole thing. He's the one who tried to rip my tunic off and Floyd had to intervene.
        
        Floyd smiles when he sees me.
    #No. It was his choice.
        I'm grateful but it was his choice to protect me. I don't want to take responsibility of what happened. 
        
        Floyd smiles when he sees me.
    #It was me.
        I bite my lip and try to look away, to tear my gaze off his back. I can't ask him if he's alright, what kind of a question that would be? 
        
        Did it hurt? No! That would be an even stupider question. 
            
        Finally, I say the most appropriate thing that comes to mind: "Thank you."
        
        Floyd smiles.
His gaze is clouded. He must've been given some kind of remedy to ease the pain.
        
"I would do it again," he whispers.
        
I shake my head at the absurdity. Why would he say that? "Why?"
        
"We're in this together."
        
Don't give me that.

"You have a wife and children. You should think about them."

He gives me another smile. "They know I could die. I told them not to worry about it."
        
"Who says that to their children?" I accuse him with a little smile.
        
"I did, apparently. You shouldn't worry. They're a tough lot." Then, he grimaces. "I'm tired of people getting hurt. If I can do something to prevent that…" He sighs. "Want to hear a joke?"

"What? Is this really a time to—"

"How do Romans cut their hair?"

"No—"

"With a pair of Caesars!" He starts chuckling against the bed.

*fake_choice
    #"Floyd, no. That was stupid."
        That just makes him chuckle more. "Did you get it?"
        
        "Yes, I got it."
        
        Then, he grimaces.
        
        "Don't laugh, you'll hurt yourself."
        
        "Comedy is worth pain." He gives me a goofy smile.
        
        "Not that kind of comedy, please."
        
        Again, he starts chuckling.
    #Chuckle. That was bad but still kind of good.
        Encouraged by my laughter, he starts chuckling louder.
        
        Then, he grimaces.
        
        "Don't laugh, you'll hurt yourself."
        
        "Comedy is worth pain." He gives me a goofy smile.
        
        We continue chuckling.
    #Shake my head in disappointment.
        That was such a bad joke. I'm not sure if his battered state can even begin to justify that.
        
        Still, he chuckles at his own joke.

"I'm sorry but…" His eyes fall close. "I think they gave me poppies. It's… making me sleepy."

Before I can answer, he's already asleep. I suppose there's nothing for me to do here. So, with a slightly lighter step, I leave. 
*goto_scene chapter5_dates ch5_dates 